import QtQuick;
import "../Flowee" as Flowee;
import "../mobile" as Mobile;

Mobile.Page {
    id: root
    headerText: qsTr("Import From Seed")

    required property QtObject pageData; // the QMLData C++ class.

    property bool fullyKnown: {
        // This page should only be used when QMLData returns seedKnown as true.
        // So the question is, are there any other details that are unknown.
        for (let id in pageData.matchingAccounts) {
            if (!pageData.fullMatch(id))
                return false;
        }
        return true;
    }

    Flickable {
        id: flickable
        anchors.fill: parent
        Column {
            width: parent.width
            spacing: 20
            Item {
                width: parent.width
                height: 100
                Image {
                    id: theLogo
                    source: "qrc:/backup-sync/nfc-tag.svg"
                    smooth: true
                    width: 100
                    height: 100
                }

                Flowee.Label {
                    anchors.left: theLogo.right
                    anchors.leftMargin: 6
                    anchors.right: parent.right
                    anchors.verticalCenter: theLogo.verticalCenter
                    text: qsTr("Imported seed is known")
                    font.pixelSize: root.font.pixelSize * 1.4
                    wrapMode: Text.WrapAtWordBoundaryOrAnywhere
                }
            }

            Repeater {
                model: pageData.matchingAccounts

                Item {
                    width: flickable.width
                    height: column.height
                    Rectangle {
                        anchors.fill: parent
                        color: palette.base
                        radius: 6
                    }
                    Column {
                        id: column
                        width: parent.width
                        spacing: 6
                        Mobile.AccountListItem {
                            id: ali
                            height: implicitHeight
                            width: parent.width
                            account: portfolio.account(modelData)
                        }

                        Rectangle {
                            id: archiveButton
                            property bool startedArchived: ali.account.isArchived
                            visible: startedArchived
                            height: visible ? archiveButtonText.height + 20 : 0
                            color: Pay.useDarkSkin ? "#b39554" : "#e5be6b"
                            width: archiveButtonText.width + 30
                            radius: 3
                            anchors.right: ali.right
                            anchors.rightMargin: 6

                            Flowee.Label {
                                id: archiveButtonText
                                text: ali.account.isArchived ? qsTr("Unarchive") : qsTr("Archive")
                                anchors.centerIn: parent
                                color: "black"
                            }
                            MouseArea {
                                anchors.fill: parent
                                cursorShape: Qt.ArrowCursor
                                onClicked: ali.root.account.isArchived = !ali.root.account.isArchived
                            }
                        }
                        Flowee.CheckBox {
                            id: privateCheckbox
                            width: parent.width
                            checked: ali.account.isPrivate
                            text: qsTr("Hide in private mode")
                            onClicked: ali.account.isPrivate = checked
                        }
                        Item { width: 1; height: 1 }
                    }
                }
            }
        }
    }
}